Na aula anterior apreendemos: Se eu tiver muito dinheiro então vou fazer uma viagem pra Disney senão vou ficar em casa

Agora veremos outra situação: Se eu tiver muito dinheiro então vou fazer uma viagem pra Disney senão Se tiver uma graninha então vou visitar minha cidade natal senão vou ficar em casa

Utilizando o Visualg:

Se (situação 1) entao
		**Bloco A**
senao
    Se (situação 2) entao
				**Bloco B**
		senao
				**Bloco C**
		FimSe
FimSe		

Se (dinheiro >= 10000) entao
		Escreva("Partiu Disney")
senao
		Se (dinheiro >= 5000) e (dinheiro < 10000) entao
			Escreva ("Visitar família")
		senao
			Escreva("#chateado")
		FimSe
FimSe

Condicional Alinhada

Prática 01: Aluno aprovado, reprovado ou em recuperação?

algoritmo "Aluno"
var
   N1, N2, M: Real
inicio
      Escreva("Primeira Nota: ")
      Leia(N1)
      Escreva("Segunda Nota: ")
      Leia(N2)
      M <- (N1 + N2)/2
      Escreval("A media do aluno foi ", M:4:2)
      Se (M >= 7) entao
         Escreval("Aluno em APROVADO")
      senao
           Se (M >= 5) e (M < 7) entao
              Escreval("Aluno em RECUPERAÇÃO")
           senao
                Escreval("Aluno REPROVADO")
           FimSe
      FimSe
fimalgoritmo

Prática 02: Cálculo do IMC

$$ IMC = Massa/Altura^2 $$

algoritmo "CalculoIMC"
var
   M, A, IMC: Real
inicio
      Escreva("Massa (Kg): ")
      Leia(M)
      Escreva("Altura (m): ")
      Leia(A)
      IMC <- M / (A ^ 2)
      Escreval("IMC: ", IMC:5:2)
      Se (IMC < 17) entao
         Escreval("Muito abaixo do peso")
      senao
           Se (IMC >= 17) e (IMC <= 18.5) entao
              Escreval ("Abaixo do peso")
           senao
                Se (IMC >= 18.5) e (IMC < 25) entao
                   Escreval("Peso ideal")
                senao
                     Se (IMC >= 25) e (IMC < 30) entao
                        Escreval ("Sobrepeso")
                     senao
                          Se (IMC >= 30) e (IMC < 35) entao
                             Escreval ("Obesidade")
                          senao
                               Se (IMC >= 35) e (IMC < 40) entao
                                  Escreval ("Obesidade severa")
                               senao
                                    Escreval("Obesidade Morbida")
                               FimSe
                          FimSe
                     FimSe
                FimSe
           FimSe
      FimSe
fimalgoritmo

Estrutura Condicional: Escolha caso

**Escolha** (**variável**)
 **Caso valor**
	 **Bloco A**
 **Caso valor**
	 **Bloco B**
 **Caso valor** 
	 **Bloco C**
 **OutroCaso**
	 **Bloco D** 
**FimEscolha**

Prática 03: Criança esperança

algoritmo "Escolha"
var
   D: Inteiro
   Valor: Real
inicio
      Escreval("---------------------------------")
      Escreval("         Criança Esperanca       ")
      Escreval("---------------------------------")
      Escreval("Muito obriagdo por ajudar ")
      Escreval(" [1] para doar R$10 ")
      Escreval(" [2] para doar R$25 ")
      Escreval(" [3] para doar R$50 ")
      Escreval(" [4] para doar outros valores ")
      Escreval(" [5] para cancelar ")
      Leia(D)
      Escolha D
              Caso 1
                   Valor <- 10
              Caso 2
                   Valor <- 25
              Caso 3
                   Valor <- 50
              Caso 4
                   Escreva ("Qual o valor da doacao? R$")
                   Leia (Valor)
              Caso 5
                   Valor <- 0
      FimEscolha
      Escreval ("------------------------")
      Escreval (" SUA DOACAO FOI DE R$", Valor)
      Escreval ("MUITO OBRIGADO!")
      Escreval ("------------------------")
fimalgoritmo

Prática 04: Quantidade de dependentes de um funcionário

algoritmo "Escolha"
var
   Nome: Caractere
   Sal, NSal: Real
   Dep: Inteiro
inicio
      Escreva ("Qual o nome do Funcionario? ")
      Leia(Nome)
      Escreva ("Qual o salario do Funcionario? R$")
      Leia(Sal)
      Escreva ("Qual e a quantidade de dependentes? ")
      Leia(Dep)
      Escolha Dep
              Caso 0
                   NSal <- Sal + (Sal*5/100)
              Caso 1, 2, 3
                   NSal <- Sal + (Sal*10/100)
              Caso 4, 5, 6
                   NSal <- Sal + (Sal*15/100)
              OutroCaso
                   NSal <- Sal + (Sal*18/100)
      FimEscolha
      Escreval ("O novo salario de ", Nome, " sera de R$", NSal:5:2)
fimalgoritmo

Exercício 01: Aproveitamento de um aluno