Repita bloco Ate expressão

algoritmo "Somador"
var
   N, Cont, S: inteiro
inicio
      S <- 0
      Cont <- 1
      Enquanto(Cont <= 5) faca
           Escreva("Digite o ", Cont, "o. valor ==> ")
           Leia(N)
           S <- S + N
           Cont <- Cont + 1
      FimEnquanto
      Escreval("A soma de todos os valores digitados e ", S)
fimalgoritmo

algoritmo "Somador2"
var
   N, S: inteiro
   resp: Caractere
inicio
      S <- 0
      resp <- "S"
      Enquanto(resp = "S") faca
           Escreva("Digite o valor ==> ")
           Leia(N)
           S <- S + N
           Escreva("Voce quer continuar? [S/N] ")
           Leia(resp)
      FimEnquanto
      Escreval("A soma de todos os valores digitados e ", S)
fimalgoritmo

Enquanto não arrumar o quarto faca castigo FimEnquanto liberado

repita castigo
Ate arrumar o quarto liberado

algoritmo "Somador"
var
   N, S: Inteiro
   resp: caractere
inicio
      S <- 0
      Repita
           Escreva("Digite o valor ==> ")
           Leia(N)
           S <- S + N
           Escreva("Voce quer continuar? [S/N] ")
           Leia(resp)
      Ate (resp = "N")
      Escreval("A soma de todos os valores digitados e ", S)
fimalgoritmo

Prática 01: contar de 1 até 10

algoritmo "Conta1a10"
var
   cont: inteiro
inicio
      cont <- 1
      Repita
         Escrevl(cont)
         cont <- cont + 1
      Ate (cont > 10)
fimalgoritmo

Adicional: exibir a tabuada de um número qualquer

algoritmo "Conta1a10"
var
   cont, N, R: inteiro
inicio
      cont <- 1
      N <- 7
      Repita
         R <- N * cont
         Escreval(N, " X ", cont, " = ", R)
         cont <- cont + 1
      Ate (cont > 10)
fimalgoritmo

algoritmo "Conta1a10"
var
   cont, N, R: inteiro
inicio
      cont <- 1
      Escreva("Quer ver a tabuada de qual numero? ")
      Leia(N)
      Repita
         R <- N * cont
         Escreval(N, " X ", cont, " = ", R)
         cont <- cont + 1
      Ate (cont > 10)
fimalgoritmo

Prática 02: quantos números são negativos?

algoritmo "ContaNegativos"
var
   N, C, TotN: inteiro
inicio
      C <- 1
      TotN <-0
      Repita
          Escreva("Digite um numero: ")
          Leia(N)
          Se (N < 0) entao
                TotN <- TotN + 1
          FimSe
          C <- C + 1
      Ate (C > 5)
      Escreval("Foram digitados ", TotN, " valores negativos.")
fimalgoritmo

Prática 03: fatorial de um número

algoritmo "Fatorial"
var
   C, N, F: Inteiro
inicio
      Escreva("Digite um numero: ")
      Leia(N)
      C <- N
      F <- 1
      Repita
          Escreva(C, " X ")
          F <- F * C
          c <- C - 1
      Ate (C < 1)
      Escreva("O valor do fatorial de ", N, " e igual a ", F)
fimalgoritmo

algoritmo "Fatorial"
var
   C, N, F: Inteiro
inicio
      Escreva("Digite um numero: ")
      Leia(N)
      C <- N
      F <- 1
      Repita
          F <- F * C
          c <- C - 1
      Ate (C < 1)
      Escreva("O valor do fatorial de ", N, " e igual a ", F)
fimalgoritmo

Adicional: fazer isso acontecer muitas vezes

algoritmo "Fatorial"
var
   C, N, F: Inteiro
   R: caractere
inicio
    Repita
      Escreva("Digite um numero: ")
      Leia(N)
      C <- N
      F <- 1
      Repita
          F <- F * C
          c <- C - 1
      Ate (C < 1)
      Escreva("O valor do fatorial de ", N, " e igual a ", F)
      Escreval("Quer continuar? [S/N]")
      Leia(R)
      LimpaTela
    Ate (R = "N")
fimalgoritmo

Prática 04: é um número primo?

algoritmo "NumeroPrimo"
var
   C, N, contDiv: inteiro
inicio
    C <- 1
    Escreva("Digite um numero: ")
    Leia(N)
    Repita
        Escreval(C)
        Se (N % C = 0) entao
             contDiv <- contDiv + 1
        FimSe
        C <- C + 1
    Ate (C > N)
    Escreval (" Ao todo existem", contDiv, " valores divisiveis.")
fimalgoritmo